>Another .bat I use, since the night I typed "expirex -r" by mistake:
>YEXPIRE.BAT
>
> set YARN=d:\yarn
> set HOME=d:\mwilson
> d:\yarn\expirex.exe -o
>
> Regards. Mel.
Posting batfiles, are we? Check this one out! :o)
My main batfile for Yarn, YAWN.BAT :
@echo off
call c:\art\bat\sæt.bat
set yarn=c:\soft\yarn
set home=c:\art\xxx\yawn
set mailcaps=c:\soft\yarn\mailcap
set path=%path%c:\soft\ss;c:\soft\qpv;
if .%1==.? goto query
if .%1==.x goto x
if .%1==.info goto info
if .%1==.sort goto sort
if .%1==.yarn goto yarnstart
if .%1==.back goto back
if .%1==.unback goto unback
if .%1==.dige goto dige
if .%1==.edit goto edit
:replyzip
if exist c:\soft\yarn\reply.zip goto import
if exist c:\soft\windows\souper\out\*.* pkzip c:\soft\yarn\reply c:\soft\windows\souper\out\*.* -m
if not exist c:\soft\windows\souper\out\nul md c:\soft\windows\souper\out
goto import
:import
if not exist c:\soft\windows\souper\in\areas goto yarnstart
if exist c:\soft\windows\souper\in\backup.zip del c:\soft\windows\souper\in\backup.zip
pkzip c:\soft\windows\souper\in\backup c:\soft\windows\souper\in\*.* -x*.zip
c:\soft\yarn\import -u c:\soft\windows\souper\in
:yarnstart
if .%1==.jez set home=c:\who\jez\xxx\yawn
if not .%1==.yarn every day c:\soft\yarn\expirex -o
call c:\art\bat\mkey.bat
c:\soft\yarn\yarnx
call c:\art\bat\mkey.bat x
goto end
:query
echo.
echo YAWN.BAT
echo.
echo YAWN - Starts Yarn for rare
echo YAWN X - Expires and free a lot of space
echo YAWN JEZ - Starts Yarn for JEZ
echo YAWN INFO - Shows some info about the NEWS.DAT
echo YAWN SORT - Sorts folders, ACTIVE and NEWSRC files
echo YAWN YARN - Just start Yarn without any processing
echo YAWN BACK - Update the backup files
echo YAWN UNBACK - Unpack the existing backup files
echo YAWN DIGE - Process digest-file
echo YAWN EDIT folder - Edit a specific folder
echo.
goto end
:info
mode 80 50
c:\soft\yarn\extra\nnignd /s2853
goto end
:sort
for %%a in (c:\art\xxx\yawn\mail\*.*) do c:\soft\yarn\extra\yarnutil\sortfold /od /q /b- %%a
sort c:\soft\yarn\active > c:\soft\yarn\active.srt
move c:\soft\yarn\active.srt c:\soft\yarn\active >nul
sort c:\art\xxx\yawn\yarn\newsrc > c:\art\xxx\yawn\yarn\newsrc.srt
move c:\art\xxx\yawn\yarn\newsrc.srt c:\art\xxx\yawn\yarn\newsrc >nul
goto end
:back
if exist c:\soft\yarn\backup.zip del c:\soft\yarn\backup.zip
if exist c:\art\xxx\yawn\yarn\backup.zip del c:\art\xxx\yawn\yarn\backup.zip
if exist c:\art\xxx\yawn\mail.zip del c:\art\xxx\yawn\mail.zip
if exist c:\who\jez\xxx\yawn\yarn\backup.zip del c:\who\jez\xxx\yawn\yarn\backup.zip
if exist c:\who\jez\xxx\yawn\mail.zip del c:\who\jez\xxx\yawn\mail.zip
if exist c:\soft\windows\soupback.zip del c:\soft\windows\soupback.zip
pkzip c:\soft\yarn\backup c:\soft\yarn\*.* -rp -x*.exe -xc:\soft\yarn\extra\*.* -ef
pkzip c:\art\xxx\yawn\yarn\backup c:\art\xxx\yawn\yarn\*.* -rp -x*.snd
pkzip c:\art\xxx\yawn\mail c:\art\xxx\yawn\mail\*.*
pkzip c:\who\jez\xxx\yawn\yarn\backup c:\who\jez\xxx\yawn\yarn\*.* -rp -x*.snd
pkzip c:\who\jez\xxx\yawn\mail c:\who\jez\xxx\yawn\mail\*.*
pkzip c:\soft\windows\soupback c:\soft\windows\souper\*.*
echo.
goto end
:unback
echo.
echo Press 'Y' if you are sure you want to restore the Yarn newsbase from
echo the present backup..
echo Press 'N' to cancel..
echo.
choice /cyn
echo.
if errorlevel 2 goto end
pkunzip c:\soft\yarn\backup c:\soft\yarn -d -o
pkunzip c:\art\xxx\yawn\yarn\backup c:\art\xxx\yawn\yarn\backup -d -o
pkunzip c:\who\jez\xxx\yawn\yarn\backup c:\who\jez\xxx\yawn\yarn -d -o
goto end
:dige
if exist c:\soft\windows\souper\in\*.msg goto end
if not exist c:\art\xxx\yawn\mail\babble goto end
c:
cd \soft\windows\souper\in
\soft\yarn\extra\yarnutil\sendfold \art\xxx\yawn\mail\babble
if exist *.msg del \art\xxx\yawn\mail\babble
\soft\yarn\extra\ddigest\ddigest -s \soft\yarn\extra\ddigest\babble.cfg .
del 00000000.msg
copy ..\areas.dig areas
echo.
echo.
echo The Soup-packet should be initialized for BABBLE import now..
echo.
goto end
:edit
c:
cd \art\xxx\yawn\mail
if not exist %2 goto end
copy %2 c:\temp\%2.bak
\soft\yarn\extra\yarnutil\editfold /t %2 %2.txt
c:\soft\qedit\q %2.txt
del %2
\soft\yarn\extra\yarnutil\editfold /f %2.txt %2
del %2.txt
echo.
echo Done!
echo.
goto end
:x
c:\soft\yarn\expirex -o
c:\soft\special\touch c:\soft\yarn\expirex.exe
if exist c:\soft\windows\souper\in\backup.zip del c:\soft\windows\souper\in\backup.zip
if exist c:\art\xxx\yawn\yarn\*.snd del c:\art\xxx\yawn\yarn\*.snd
if exist c:\who\jez\xxx\yawn\yarn\*.snd del c:\who\jez\xxx\yawn\yarn\*.snd
c:\art\pas\yfut x 100 15
goto end
:end
Beat that, anyone? :)
--
/\ M O R T E N N I E L S E N
/ \ r a r e @ c y b e r n e t . d k
/__ /\ __\
/____\ rare 96