I'm including the batch file I use with Yarn (shouldn't change for
Yarn95, as I understand the differences between the two). A
couple of notes:
1) This is written for 4DOS and takes advantage of some of the
advanced batch feature of that command processor. I don't think
this obscures the logic, but write and ask if you've got any
questions. It's also got some historical artifacts from the
original version of this which was used with a uqwk download.
2) This splits mail and news retrieval because we were having
difficulties with the process hanging during the latter. Our ISP
seems to have fixed whatever was behind this, because news has
been much better behaved of late.
3) For the same reason as in (1), the batch file saves backup
copies of the AREAS and *.MSG files. It uses a 4DOS feature to
create a unique subdirectory for saving the info and copies the
files in before importing them.
Hope this helps.
Dave Lemire (borrowing wife's ISP account)
=================== begin SKEIN4.BAT ===================
@echo off
::
:: Skein -- a batch file to organize YARN operations
:: -- Version 4, using SOUPER95 to gather traffic
:: -- separate mail and news calls to ensure we get mail
::
:START
setlocal
SET NNTPSERVER=news3.qis.net
path=%path$;c:\utils
E:
:GATHER
:: first decide whether or not to call
if exist e:\internet\souper95\0000000.MSG goto IMPORT
inkey /k"YN" Call QIS to download traffic? (y/n) ? %%callQIS
if "%callQIS"=="n" goto IMPORT
:GATHER1
:: call QIS for a download
:: (4dos feature: CDD = change drive and directory)
*cdd E:\internet\souper95
:GATHER_MAIL
:: get mail and save copy for safety
souper95 -n -x -h e:\internet\souper95 mail.qis.net pennyl delta1
if not exist e:\internet\souper95\0000000.MSG (echo "No Mail, Getting News" ^ goto GATHER_NEWS)
Echo Mail retrieved, saving backup copy...
:: use 4DOS built-in environment variables
:: to create unique subdir name
md MAIL%_DOY%%_DOW%%_HOUR
copy *.msg AREAS MAIL%_DOY%%_DOW%%_HOUR
*cdd e:\internet\yarn
set HOME=e:\internet\yarn
set YARN=e:\internet\yarn
e:import -u e:\internet\souper95
unset HOME YARN
:GATHER_NEWS
:: get news and save copy for safety
*cdd E:\internet\souper95
souper95 -m -x -h e:\internet\souper95
if not exist e:\internet\souper95\0000001.MSG (echo "No News, Starting YARN" ^ goto IMPORT)
Echo News retrieved, saving backup copy...
md NEWS%_DOY%%_DOW%%_HOUR
copy *.msg AREAS NEWS%_DOY%%_DOW%%_HOUR
Beep ^ Beep ^ Beep
Echo Don't forget to disconnect from Quantum
:IMPORT
*cdd e:\internet\yarn
if not exist e:\internet\souper95\AREAS goto RUN_YARN
inkey /k"YN" Import new traffic? (y/n) ? %%import
if "%import"=="n" goto ASK_FIX
set HOME=e:\internet\yarn
set YARN=e:\internet\yarn
e:import -u e:\internet\souper95 ^ pause ^ goto RUN_YARN
unset HOME YARN
:ASK_FIX
:: this gives access to a "save what we can" batch file
:: I created when we were aborting a lot of downloads
inkey /k"YN" Run FixImport for interrupted download? (y/n) ? %%fix
if "%fix"=="y" call FIXIMPORT
:RUN_YARN
set HOME=e:\internet\yarn
set YARN=e:\internet\yarn
e:yarnx
e:expirex -r
unset HOME YARN
:SEND
if not exist e:\internet\souper95\reply.qis goto ALL_DONE
inkey /k"YN" Call QIS to send replies? (y/n) ? %%callQIS
if "%callQIS"=="n" goto ALL_DONE
:: call QIS to send replies
*cdd E:\internet\souper95
unzip reply.qis
souper95 -s mail.qis.net pennyl delta1
Beep
Echo Don't forget to disconnect from Quantum
:FINISH
inkey /k"YN" Delete replies (y/n)? (Delete if sent successfully): %%delREPLIES
if "%delREPLIES"=="n" goto ALL_DONE
del e:\internet\souper95\reply.qis
:: see if user want to do another download
inkey /k"YN" Download traffic again (y/n) ? %%call_QIS_again
if "%call_QIS_again"=="n" goto ALL_DONE
GOTO GATHER1
:ALL_DONE
endlocal
=================== end SKEIN4.BAT ===================